Druid Macros

Hearth/Teleport to Moonglade/Have Group, Will Travel

Combines your hearthstone, Moonglade teleport and group summon guild perk into a single button. Left click will always hearth. When not in a group and right clicking will teleport to Moonglade. When in a group right clicking will summon your group and hold down a modifier and right clicking will teleport to Moonglade.

#showtooltip
/cast [btn:2,group,nomod] Have Group, Will Travel; [btn:2] Teleport: Moonglade; Hearthstone

Barkskin/Mark of the Wild

I wanted to make my druid buff more accessible, but not take up another precious hot key so I combined it with barkskin which I never use out of combat (and this macro ensure that I never will on accident either). So in combat barkskin will be used, unless a modifier is pressed for buffing in the middle of combat. Out of combat mark of the wild will be used.

#showtooltip
/use [nomod,combat] Barkskin; Mark of the Wild

Resurrect with Announcement

With multiple people able to resurrect it is helpful to let everyone around you know that you are doing it. This macro also combines Rebirth and Revive so you never accidentally use your battle rez out of combat in addition to putting them both on a single button. Now with mass resurrection!

#showtooltip
/use [combat] Rebirth; [btn:2] Mass Resurrection; Revive
/run SendChatMessage("I am reviving "..SecureCmdOptionParse("[btn:2,nocombat]everybody!;[noexists][nodead]somebody nearby.;%t!"))

Power Shift

Kind of a misnomer at this point seeing as this won't give you more energy in cat form anymore, but it still provides a way to generate a little rage in a pinch when talented for it. Mostly it is a means to shift out of your current form and back into the same form with one button and remove any movement impairing effects. Since cataclysm removed the ambiguity for form:5 this macro now works for all druid specs without modification.

#showtooltip
/cast [form:1] !Bear Form; [form:2] !Aquatic Form; [form:3] !Cat Form; [form:4] !Travel Form; [form:5] !Moonkin Form; [nocombat,flyable] !Swift Flight Form; !Travel Form

Healing Spell/Damage Spell

There are a lot of healing spells and a lot of damage spells, neither of which are particularly useful to a feral druid, and only half of them are useful for a balance or restoration druid. So I combined the majority of healing/damage spells into single buttons which change depending on target to save a bit of space. When a hostile target is selected the button will use a damage spell and when a friendly target or no target is selected a heal will be cast. Using the alt modifier will do a self heal.

#showtooltip
/cast [mod,@player][noharm] Regrowth; Starfire

#showtooltip
/cast [mod,@player][noharm] Nourish; Wrath

#showtooltip
/cast [mod,@player][noharm] Rejuvenation; Moonfire

#showtooltip
/cast [mod,@player][noharm] Lifebloom; Insect Swarm

Cleanse/Soothe

Cleanses a friendly target of a poison, curse or possibly a magic effect if resto or if a hostile target is selected it will cast soothe to remove an enrage effect. Using the alt modifier will self cleanse.

#showtooltip
/use [mod,@player][noharm] Remove Corruption; Soothe

Cat "Stealth Bar" and Feral Consolidation

There are a few more cat abilities that can actually fit on your cat bar (ditto for bears). The cat overcrowding stems from the fact that cats don't benefit from a separate stealth bar like rogues do, but you can use macros to emulate one.

Bears on the other hand just have too many abilities to fit on your bear form bar, period. One option would be to put some abilities up onto other bars which are accessible all the time, but then you have to look at unusable abilities when you aren't in bear form. My solution was to combine a few related abilities to make it all fit.

Once you start making macros for all these different druid abilities you actually start to run out of slots to create macros. In fact using all of the macros on this page will fill every slot (assuming one macro spot reserved for mounts). To keep my number of macros down I've combined each of my cat macros with a bear macro and just added the additional check to see what form I am in. The following few macros employ all three of these ideas.

Cat: Ravage/Shred, Bear: Challenging Roar/Growl

When in cat form use ravage while stealthed, otherwise use shred. When in bear form use growl and if a modifier is pressed use challenging roar.

#showtooltip
/use [stealth] Ravage; [form:1,mod] Challenging Roar; [form:1] Growl; Shred

Cat: Pounce/Shred, Caster: Nature's Swiftness/Healing Touch

This one is a little different, instead of sneaking in a bear ability I included a caster ability. Since caster form and moonkin form are both mutually exclusive as are cat and bear form it is possible to combine a macro that does something different in up to all four cases. Something to keep in mind should you choose to customize some of this.

When in cat form use pounce while stealthed, otherwise use rake. When not in cat form (i.e. caster/tree form) use nature's swiftness and healing touch. I have an extra check to make sure I am in my secondary spec before casting nature's swiftness since my other spec is feral. You can replace [spec:2] with [spec:1] if your primary spec is restoration or remove it completely since you don't have to have it on your bar in specs that don't make sense.

#showtooltip
/use [noform:3,spec:2] Nature's Swiftness
/use [noform:3] Healing Touch
/stopmacro [noform:3]
/use [stealth] Pounce; Rake

Cat: Prowl/Ferocious Bite, Bear: Swipe/Thrash

When in cat form use ferocious bite while in combat or not stealthed, otherwise use prowl. Since you can't stealth in combat, and also will never use a finisher while stealthed over an opener, it is convenient to combine prowl and a finishing move.

When in bear form use a castsequence that alternates swipe and thrash. Since swipe is cheaper I stuck it first in the sequence since at the start of a pull it is more likely to be available. Added another swipe at the end since swipe's cooldown was lowered to 3 seconds from 6.

#showtooltip
/castsequence [form:1] reset=6 Swipe(Bear), Thrash, Swipe(Bear)
/use [combat,nostealth] Ferocious Bite; Prowl

Universal Faerie Fire plus Marking

When in cat or bear forms Feral Faerie Fire will be used and regular Faerie Fire otherwise. Since I use this ability to pull while tanking I also incorporated a way to quickly mark a target with a skull and let people know to attack it.

#showtooltip
/cast [form:1/3] Faerie Fire (Feral)(); Faerie Fire
/stopmacro [btn:1]
/run SetRaidTarget("target",8)
/s Please assist me in killing %t {Skull}!

Crowd Control a Focus Target

Druids have quite a few crowd control options available and there are times when you'd like to focus on keeping a particular target locked down. The following macros will crowd control your focus target if your focus target is alive and hostile, otherwise the ability will behave as usual and cast on your current target or switch to a hand cursor to select a target if you didn't have anything targeted.

If you don't currently have a focus target or your focus target is dead using one of these macros will set your focus to be your current target. Right clicking won't cast anything, but will force your focus to your current target no matter what. I often use these macros to set a focus target for whatever reason.

Finally sometimes druids will crowd control more than one target, but we only have one focus to work with. Holding down a modifier will crowd control you current target and ignore your focus if you have one and set it if you didn't.

#showtooltip
/focus [btn:2][@focus,noexists][@focus,dead]
/stopmacro [btn:2]
/use [mod][@focus,exists,nodead,harm][] Entangling Roots

#showtooltip
/focus [btn:2][@focus,noexists][@focus,dead]
/stopmacro [btn:2]
/use [mod][@focus,exists,nodead,harm][] Hibernate

#showtooltip
/focus [btn:2][@focus,noexists][@focus,dead]
/stopmacro [btn:2]
/use [mod][@focus,exists,nodead,harm][] Cyclone